/\*

**Controlled-trial programs.**

For crossover programs see **crossover two predictors SAS.docx.**

\*/

**\*import the wide dataset;**

\*specify your path name in the filename statement;

\*or import the data directly by double-clicking **controlled trial data wide.xlsx** in SAS Studio;

FILENAME REFFILE '/folders/myfolders/Mixed-model Workshop/Controlled-trial models/controlled trial data wide.xlsx';

PROC IMPORT DATAFILE=REFFILE

DBMS=XLSX replace

OUT=import;

GETNAMES=YES;

RUN;

**\*display import;**

proc print;run;

**\*set up options for proc mixed output;**

ods noproctitle;

ods graphics / imagemap=on;

**title "Analyzing change scores";**

proc mixed data=import plots(only)=StudentPanel(conditional) alpha=0.1 nobound;

class Name Group;

model Post\_Pre=Group/residual;

random xVarExp/subject=Name;

\*random xVarExp\*Name; \*this does the same thing as the above line;

lsmeans Group/diff=control("Control") cl alpha=0.1;

run;

**title "Analyzing change scores, plus a modifying covariate";**

proc mixed data=import plots(only)=StudentPanel(conditional) alpha=0.1 nobound;

class Name Group;

model Post\_Pre=Group Group\*X/noint solution ddfm=sat residual alpha=0.1;

random xVarExp/subject=Name;

\*random xVarExp\*Name; \*this does the same thing as the above line;

lsmeans Group/diff=control("Control") cl alpha=0.1;

estimate "Means @ X=9.15:";

estimate " Control" Group 1 0 Group\*X 9.15 0/cl alpha=0.1;

estimate " Exptal" Group 0 1 Group\*X 0 9.15/cl alpha=0.1;

estimate " Exptal-Control" Group -1 1 Group\*X -9.15 9.15/cl alpha=0.1;

estimate "Effect of X:";

estimate " Control x1" Group\*X 1 0/cl alpha=0.1;

estimate " Exptal x1" Group\*X 0 1/cl alpha=0.1;

estimate " Exp-Con x1" Group\*X -1 1/cl alpha=0.1;

estimate "";

estimate " Control x2SD" Group\*X 6.61 0/cl alpha=0.1;

estimate " Exptal x2SD" Group\*X 0 6.61/cl alpha=0.1;

estimate " Exp-Con x2SD" Group\*X -6.61 6.61/cl alpha=0.1;

run;

\*changes to the above proc mixed to add **sex as a covariate** are shown tracked;

**title "Analyzing change scores, plus sex and a modifying covariate";**

proc mixed data=import plots(only)=StudentPanel(conditional) alpha=0.1 nobound;

class Name Sex Group;

model Post\_Pre=Sex\*Group Sex\*Group\*X/noint solution ddfm=sat residual alpha=0.1 ddfm=sat;

random xVarExp/subject=Name group=Sex;

repeated/group=Sex;

lsmeans Sex\*Group;

lsmestimate Sex\*Group

"Female Exp-Con" -1 1 0 0,

"Male Exp-Con" 0 0 -1 1,

"Male-Female Exp-Con" 1 -1 -1 1/cl alpha=0.1;

estimate "Effect of X:";

estimate " Female Con x1" Sex\*Group\*X 1 0 0 0/cl alpha=0.1;

estimate " Female Exp x1" Sex\*Group\*X 0 1 0 0/cl alpha=0.1;

estimate " Female Exp-Con x1" Sex\*Group\*X -1 1 0 0/cl alpha=0.1;

estimate "";

estimate " Female Con x2SD" Sex\*Group\*X 6.61 0 0 0/cl alpha=0.1;

estimate " Female Exp x2SD" Sex\*Group\*X 0 6.61 0 0/cl alpha=0.1;

estimate " Female Exp-Con x2SD" Sex\*Group\*X -6.61 6.61 0 0/cl alpha=0.1;

estimate "";

estimate " Male Exp-Con x2SD" Sex\*Group\*X 0 0 -6.61 6.61/cl alpha=0.1;

estimate "";

estimate " Male-Female Exp-Con x2SD" Sex\*Group\*X 6.61 -6.61 -6.61 6.61/cl alpha=0.1;

run;

\*changes to add an **extra modifying covariate** (instead of sex) are shown tracked;

**title "Analyzing change scores, plus two modifying covariates";**

title2 "Compare with the spreadsheet at sportsci.org";

proc mixed data=import plots(only)=StudentPanel(conditional) alpha=0.1 nobound;

class Name Group;

model Post\_Pre=Group Group\*X Group\*LnPre/noint solution ddfm=sat residual alpha=0.1;

random xVarExp/subject=Name;

\*random xVarExp\*Name; \*this does the same thing as the above line;

lsmeans Group/diff=control("Control") cl alpha=0.1;

estimate "Means @ X=9.15 LnPre=599.5:";

estimate " Control" Group 1 0 Group\*X 9.15 0 Group\*LnPre 599.5 0/cl alpha=0.1;

estimate " Exptal" Group 0 1 Group\*X 0 9.15 Group\*LnPre 0 599.5/cl alpha=0.1;

estimate " Exptal-Control" Group -1 1 Group\*X -9.15 9.15 Group\*LnPre -599.5 599.5/cl alpha=0.1;

estimate "Effect of X:";

estimate " Control x2SD" Group\*X 6.61 0/cl alpha=0.1;

estimate " Exptal x2SD" Group\*X 0 6.61/cl alpha=0.1;

estimate " Exp-Con x2SD" Group\*X -6.61 6.61/cl alpha=0.1;

estimate "Effect of LnPre:";

estimate " Control x2SD" Group\*LnPre 11.07 0/cl alpha=0.1;

estimate " Exptal x2SD" Group\*LnPre 0 11.07/cl alpha=0.1;

estimate " Exp-Con x2SD" Group\*LnPre -11.07 11.07/cl alpha=0.1;

run;

\*estimate statements are simpler if use proc standard to make the mean=0 and SD=0.5 for X and LnPre;

\*see **crossover two predictors SAS.docx** for the code;

\*the remaining programs are for analysis of **actual scores** using data in **long format**;

**\*import the long dataset;**

FILENAME REFFILE '/folders/myfolders/Mixed-model Workshop/Controlled-trial models/controlled trial data long.xlsx';

PROC IMPORT DATAFILE=REFFILE

DBMS=XLSX replace

OUT=WORK.IMPORT1;

GETNAMES=YES;

RUN;

**\*display import1;**

proc print;run;

**\*make a subset of Trials 2 and 3 (Pre and Post);**

data long;

set import1;

if 1<Trial<4;

run;

**title "Analyzing actual scores for Trials 2 and 3";**

proc mixed data=long plots(only)=StudentPanel(conditional) alpha=0.1 nobound;

class Name Group Trial;

model LnY=Group\*Trial/residual ddfm=sat;

random Intercept xVarExp3/subject=Name;

\*random Name xVarExp3\*Name; \*this does the same thing as the above line;

\*repeated Trial/subject=Name type=cs; \*this line plus the next…;

\*random xVarExp3\*Name; \*does the same thing as the above;

lsmeans Group\*Trial;

lsmestimate Group\*Trial

"Control Post-Pre" -1 1 0 0,

"Exptal Post-Pre" 0 0 -1 1,

"Exp-Con Post-Pre" 1 -1 -1 1/cl alpha=0.1;

run;

**title "Analyzing actual scores for Trials 2 and 3, plus a covariate";**

proc mixed data=long plots(only)=StudentPanel(conditional) alpha=0.1 nobound;

class Name Group Trial;

model LnY=Group\*Trial Group\*Trial\*X/residual ddfm=sat;

\*random Intercept xVarExp3/subject=Name;

\*random Name xVarExp3\*Name; \*this does the same thing as the above line;

repeated Trial/subject=Name type=cs; \*this line plus the next…;

random xVarExp3\*Name; \*does the same thing as the above;

lsmeans Group\*Trial;

lsmestimate Group\*Trial

"Control Post-Pre" -1 1 0 0,

"Exptal Post-Pre" 0 0 -1 1,

"Exp-Con Post-Pre" 1 -1 -1 1/cl alpha=0.1;

estimate "Effect of X:";

estimate " Control x1" Group\*Trial\*X -1 1 0 0/cl alpha=0.1;

estimate " Exptal x1" Group\*Trial\*X 0 0 1 -1/cl alpha=0.1;

estimate " Exp-Con x1" Group\*Trial\*X 1 -1 -1 1/cl alpha=0.1;

estimate "";

estimate " Control x2SD" Group\*Trial\*X -6.61 6.61 0 0/cl alpha=0.1;

estimate " Exptal x2SD" Group\*Trial\*X 0 0 -6.61 6.61/cl alpha=0.1;

estimate " Exp-Con x2SD" Group\*Trial\*X 6.61 -6.61 -6.61 6.61/cl alpha=0.1;

run;

**\*make a subset of Trials 2, 3 and 4;**

data long1;

set import1;

if 1<Trial;

run;

**title "Analyzing actual scores for Trials 2, 3 & 4, plus a covariate";**

proc mixed data=long1 plots(only)=StudentPanel(conditional) alpha=0.1 nobound;

class Name Group Trial;

model LnY=Group\*Trial Group\*Trial\*X/residual ddfm=sat;

random Intercept/subject=Name;

random xVarExp3 xVarExp4/subject=Name type=un;

lsmeans Group\*Trial;

lsmestimate Group\*Trial

"Control Post1-Pre" -1 1 0 0 0 0,

"Exptal Post1-Pre" 0 0 0 -1 1 0,

"Exp-Con Post1-Pre" 1 -1 0 -1 1 0,

"Exp-Con Post2-Pre" 1 0 -1 -1 0 1/cl alpha=0.1;

estimate "Effect of X:";

estimate " Control Post1-Pre x2SD" Group\*Trial\*X -6.61 6.61 0 0 0 0/cl alpha=0.1;

estimate " Exptal Post1-Pre x2SD" Group\*Trial\*X 0 0 0 -6.61 6.61 0/cl alpha=0.1;

estimate " Exp-Con Post1-Pre x2SD" Group\*Trial\*X 6.61 -6.61 0 -6.61 6.61 0/cl alpha=0.1;

estimate " Exp-Con Post2-Pre x2SD" Group\*Trial\*X 6.61 0 -6.61 -6.61 0 6.61/cl alpha=0.1;

run;

**\*import the data for analysis in long format with a baseline covariate;**

FILENAME REFFILE '/folders/myfolders/Mixed-model Workshop/Controlled-trial models/controlled trial data long baseline covariate.xlsx';

PROC IMPORT DATAFILE=REFFILE

DBMS=XLSX replace

OUT=WORK.IMPORT2;

GETNAMES=YES;

RUN;

**\*display import2;**

proc print;run;

**title "Analyzing actual scores for Trials 3 & 4, with X and a baseline covariate";**

proc mixed data=import2 plots(only)=StudentPanel(conditional) alpha=0.1 nobound;

class Name Group Trial;

model LnY=Group\*Trial Group\*Trial\*X Group\*Trial\*LnY2/residual ddfm=sat;

random Intercept/subject=Name;

random xVarExp3 xVarExp4/subject=Name type=un;

lsmeans Group\*Trial/cl alpha=0.1;

lsmestimate Group\*Trial

"Exp-Con Post1-Pre" -1 0 1 0,

"Exp-Con Post2-Pre" 0 -1 0 1/cl alpha=0.1;

estimate "Effect of X x2SD:";

estimate " Control Post1-Pre" Group\*Trial\*X 6.61 0 0 0/cl alpha=0.1;

estimate " Exptal Post1-Pre" Group\*Trial\*X 0 0 6.61 0/cl alpha=0.1;

estimate " Exp-Con Post1-Pre" Group\*Trial\*X -6.61 0 6.61 0/cl alpha=0.1;

estimate " Exp-Con Post2-Pre" Group\*Trial\*X 0 -6.61 0 6.61/cl alpha=0.1;

estimate "Effect of LnY2 x2SD:";

estimate " Control Post1-Pre" Group\*Trial\*LnY2 11.1 0 0 0/cl alpha=0.1;

estimate " Exptal Post1-Pre" Group\*Trial\*LnY2 0 0 11.1 0/cl alpha=0.1;

estimate " Exp-Con Post1-Pre" Group\*Trial\*LnY2 -11.1 0 11.1 0/cl alpha=0.1;

estimate " Exp-Con Post2-Pre" Group\*Trial\*LnY2 0 -11.1 0 11.1/cl alpha=0.1;

run;

**\*analyze Trials 2 and 3 in the long dataset by Sex;**

proc sort data=long;

by Sex;

title "Analyzing actual scores for Trials 2 and 3";

proc mixed data=long plots(only)=StudentPanel(conditional) alpha=0.1 nobound;

class Name Group Trial;

model LnY=Group\*Trial/residual ddfm=sat;

random Intercept xVarExp3/subject=Name;

lsmeans Group\*Trial;

lsmestimate Group\*Trial

"Control Post-Pre" -1 1 0 0,

"Exptal Post-Pre" 0 0 -1 1,

"Exp-Con Post-Pre" 1 -1 -1 1/cl alpha=0.1;

by Sex;

run;

**\*analyze Trials 2 and 3 in the long dataset with Sex in the model;**

title "Analyzing actual scores for Trials 2 and 3";

proc mixed data=long plots(only)=StudentPanel(conditional) alpha=0.1 nobound;

class Name Sex Group Trial;

model LnY=Sex\*Group\*Trial/residual ddfm=sat;

random Intercept xVarExp3/subject=Name group=Sex;

parms 30 30 0 10 10 2;

repeated/group=Sex;

lsmeans Sex\*Group\*Trial;

lsmestimate Sex\*Group\*Trial

"F Control Post-Pre" -1 1 0 0 0 0 0 0,

"F Exptal Post-Pre" 0 0 -1 1 0 0 0 0,

"F Exp-Con Post-Pre" 1 -1 -1 1 0 0 0 0,

" " 0,

"M Control Post-Pre" 0 0 0 0 -1 1 0 0,

"M Exptal Post-Pre" 0 0 0 0 0 0 -1 1,

"M Exp-Con Post-Pre" 0 0 0 0 1 -1 -1 1,

" " 0,

"F-M Exp-Con Post-Pre" 1 -1 -1 1 -1 1 1 -1,

"(F+M)/2 Exp-Con Post-Pre" 1 -1 -1 1 1 -1 -1 1 divisor=2

/cl alpha=0.1;

run;